このエントリーをはてなブックマークに追加


Win32_ComputerSystemのサンプルスクリプト

WMIを使ったWin32_ComputerSystem内のコンピュータ名、ユーザ名、ドメイン、ドメインのロールを表示する、サンプルスクリプトを以下に記します。


関連記事

Win32_ComputerSystemを使ったサンプルスクリプト

以下にWin32_ComputerSystemを使用したサンプルスクリプトを記します。
本サンプルスクリプトでは、以下の5つの値を表示しています。

  • コンピュータ名
  • ユーザ名
  • ドメイン名
  • プロセッサ数
  • ドメインのロール

サンプルスクリプト

hostname="."	' dotは自機を示す
' uid = "username"
' pwd = "password"
Set oLocater = CreateObject("WbemScripting.SWbemLocator")
Set oService = oLocater.ConnectServer(hostname, "root/cimv2")
' Set oService = oLocater.ConnectServer(hostname, "root/cimv2", uid, pwd)	'ユーザ、パスワード設定をする場合
oService.Security_.ImpersonationLevel = 3	' デフォルト値は3のため省略可能

Set items = oService.ExecQuery("Select * From Win32_ComputerSystem", , 48)

For Each item In items
  WScript.Echo("コンピュータ名: " & item.Name)
  WScript.Echo("ユーザ名: " & item.UserName)
  WScript.Echo("ドメイン名: " & item.Domain)
  WScript.Echo("プロセッサ数: " & item.NumberOfProcessors)
  Select Case item.DomainRole
    ' https://technet.microsoft.com/en-us/library/ee198796.aspx
    Case 0
      desc = "Stand-alone workstation"
    Case 1
      desc = "Member workstation"
    Case 2
      desc = "Stand-alone server"
    Case 3
      desc = "Member server"
    Case 4
      desc = "Backup domain controller"
    Case 5
      desc = "Primary domain controller"
  End Select
  WScript.Echo("ドメインのロール: " & desc)
Next

Set item = Nothing
Set oService = Nothing
Set oLocater = Nothing

実行例

cscriptを使用して実行した時の出力です。

PS C:\Users\sakura\Desktop> cscript .\comsys.vbs
Microsoft (R) Windows Script Host Version 5.8
Copyright (C) Microsoft Corporation. All rights reserved.

コンピュータ名: THINKPAD
ユーザ名: THINKPAD\sakura
ドメイン名: WORKGROUP
プロセッサ数: 1
ドメインのロール: Stand-alone workstation

以上、Win32_ComputerSystemを使ったサンプルスクリプトでした。



添付ファイル: filecomsys.vbs 622件 [詳細]

トップ   編集 凍結 差分 バックアップ 添付 複製 名前変更 リロード   新規 一覧 検索 最終更新   ヘルプ   最終更新のRSS
Last-modified: 2015-04-19 (日) 17:19:11